Outlook の自動仕分けルールを使うと、受信したメールのフラグをつけることが可能ですが、アラームを設定することができません。
また、件名に含まれるキーワードでフラグをつけるようにしていると、返信が繰り返されるたびにフラグが設定されてしまいます。

そこで、メールの受信時に特定の条件に合致すると、その条件に応じてフラグとアラームを設定し、同じスレッドのメールがある場合はそれらのフラグをクリアするマクロを作成しました。

重要なメールは受信してすぐにアラームを出し、それほど重要でない場合はちょっと時間をおいてアラームを出すようにしています。
また、営業時間外にメールを受信した場合は翌営業日の朝にアラームを設定します。
必要に応じて条件を追加・削除したり、アラームまでの時間を調整したりしてください。

なお、ワンクリックでフラグのアラームを設定するマクロ を使用している場合は赤字のコードが重複するので、これを取り除いてコピーしてください。

'
Const START_TIME = " 9:00"
Const END_TIME = " 17:00"
Const START_HOUR = 9
Const END_HOUR = 17
'
Private Sub Application_NewMailEx(ByVal EntryIDCollection As String)
     Dim objItem As Object
     '
     Set objItem = Session.GetItemFromID(EntryIDCollection)
     If objItem.MessageClass = "IPM.Note" Then
         Dim mlItem As MailItem
         Set mlItem = objItem
         CheckAndFlag mlItem
     End If
End Sub
' アイテムの内容に応じてフラグをセットする
Public Sub CheckAndFlag(ByRef objItem As MailItem)
     Dim oneRec As Recipient
     ' 重要度が高なら 5 分後
     If objItem.Importance = olImportanceHigh Then
         MarkAsTask objItem, 5
         Exit Sub
     End If
     ' 件名が重要、緊急などの文字列で始まっていたら 5 分後
     Dim arrUrgent As Variant
     Dim strUrgent As Variant
     arrUrgent = Array("重要*", "緊急*", "至急*", "大至急*")
     For Each strUrgent In arrUrgent
         If objItem.Subject Like strUrgent Then
             MarkAsTask objItem, 5
             Exit Sub
         End If
     Next
     ' 特定の差出人からのメールは 10 分後
     Dim arrSender As Variant
     Dim strSender As Variant
     arrSender = Array("Manager Name", "Manager Name2")
     For Each strSender In arrSender
         If objItem.SenderName = strSender Then
             MarkAsTask objItem, 10
             Exit Sub
         End If
     Next
     ' 自分宛てのメールは 15 分後
     For Each oneRec In objItem.Recipients
         If oneRec.Address = Session.CurrentUser.Address Then
             ' 重要度が低ならアラームは設定しない
             If objItem.Importance = olImportanceLow Then
                 Exit For
             End If
             MarkAsTask objItem, 15
             Exit Sub
         End If
     Next
     ' 件名に特定の文字列を含むメールは 60 分後
     Dim arrProject
     Dim strProject
     arrProject = Array("*ProjectA*", "*ProjectB*", "*ProjectC*")
     For Each strProject In arrProject
         If objItem.Subject Like strProject Then
             MarkAsTask objItem, 60
             Exit Sub
         End If
     Next
End Sub
' 分単位でアラームを設定する処理
Sub MarkAsTask(objItem As MailItem, iTime As Integer)
     On Error Resume Next
     Dim w
     Dim dtRemind
     Dim h
     Dim strTime
     ' スレッドの他のメールのフラグをクリア
     ClearFlagsOnConversation objItem
     '
     With objItem
         ' 今日の曜日を取得
         w = Weekday(Now)
         ' 土日に受信したメールについては月曜日の業務開始時間
         If w = vbSaturday Then
             dtRemind = DateAdd("d", Now, 2)
             strTime = START_TIME
         ElseIf w = vbSunday Then
             dtRemind = DateAdd("d", Now, 1)
             strTime = START_TIME
         Else
             ' 現在の時刻を取得
             h = Hour(Now)
             If h < START_HOUR Then
             ' 業務開始前に受信したメールは業務開始時
                 dtRemind = Now
                 strTime = START_TIME
             ElseIf h >= END_HOUR Then
             ' 業務終了後に受信したメールは翌日
                 strTime = START_TIME
                 If w = vbFriday Then
                     ' 金曜日なら月曜日に
                     dtRemind = DateAdd("d", 3, Now)
                 Else
                     dtRemind = DateAdd("d", 1, Now)
                 End If
             Else
                 ' 現在時刻に指定された分を追加
                 dtRemind = DateAdd("n", iTime, Now)
                 ' アラームが業務終了後になるなら、業務終了時に
                 If h >= END_HOUR Then
                     strTime = END_TIME
                 Else
                     strTime = " " & FormatDateTime(dtRemind, vbShortTime)
                 End If
             End If
         End If
         dtRemind = FormatDateTime(dtRemind, vbShortDate) & strTime
         MarkAsTaskCore objItem, olMarkToday, dtRemind
     End With
End Sub
' スレッドの全てのメールのフラグをクリア
Private Sub ClearFlagsOnConversation(objItem As MailItem)
     Dim objConv As Conversation
     Dim colRootItems As SimpleItems
     Dim objRootItem As Object
     Set objConv = objItem.GetConversation
     Set colRootItems = objConv.GetRootItems()
     For Each objRootItem In colRootItems
         ClearFlagsRecursive objRootItem, objConv
     Next
End Sub
' 再帰的にフラグをクリアする
Private Sub ClearFlagsRecursive(objRootItem As Object, objConv As Conversation)
     Dim colItems As SimpleItems
     Dim objItem As Object
     Set colItems = objConv.GetChildren(objRootItem)
     If colItems.Count > 0 Then
         For Each objItem In colItems
             If TypeName(objItem) = "MailItem" Then
                 ClearFlagsRecursive objItem, objConv
             End If
         Next
     End If
     With objRootItem
         If .IsMarkedAsTask Then
             .ClearTaskFlag
             .Save
         End If
     End With
End Sub

' フラグ設定の共通処理
Private Sub MarkAsTaskCore(ByVal objItem As Object, mkInt As OlMarkInterval, ByVal dtRemind As Date)
     Dim dtDue As Date
     dtDue = FormatDateTime(dtRemind, vbShortDate)
     With objItem
         .MarkAsTask mkInt
         .FlagStatus = olFlagMarked
         .FlagRequest = "ご確認ください"
         .TaskStartDate = Now
         .TaskDueDate = dtDue
         .ReminderTime = dtRemind
         .ReminderSet = True
         .Close olSave
     End With
End Sub


マクロの登録方法やメニューへの追加について

Outlook でフラグを設定する方法はマイクロソフトのサポート技術情報の「カテゴリ、フラグ、リマインダー、色を設定する」で説明されていますが、アラームを設定するには数回クリックする必要があります。

そこで、ワンクリックでアラームを設定できるようにするマクロを作成しました。

以下のそれぞれのマクロをリボンやクイック アクセス ツールバーに登録しておくことで、メッセージ一覧で選択したメールにフラグとアラームを設定できます。

マクロは以下のようになります。

'
Const START_TIME = " 9:00" ' 業務開始時刻を指定 (時刻の前にスペースが必要)
Const END_TIME = " 17:00" ' 業務終了時刻を指定 (時刻の前にスペースが必要)
' 1 時間後にアラーム
Public Sub FollowSelected1Hour()
     FollowSelectedHoursCore 1
End Sub
' 2 時間後にアラーム
Public Sub FollowSelected2Hours()
     FollowSelectedHoursCore 2
End Sub
' 3 時間後にアラーム
Public Sub FollowSelected3Hours()
     FollowSelectedHoursCore 3
End Sub
' 数時間後にアラーム設定する共通処理
Private Sub FollowSelectedHoursCore(iHour As Integer)
     On Error Resume Next
     Dim objItem 'As MailItem
     Dim dtRemind As Date
     dtRemind = DateAdd("h", iHour, Now)
     For Each objItem In ActiveExplorer.Selection
         MarkAsTaskCore objItem, olMarkToday, dtRemind
     Next
End Sub
' その日の終わりにアラーム
Public Sub FollowSelectedByEndOfTheDay()
     On Error Resume Next
     Dim objItem 'As MailItem
     Dim dtRemind As Date
     dtRemind = FormatDateTime(Now, vbShortDate) & END_TIME
     For Each objItem In ActiveExplorer.Selection
         MarkAsTaskCore objItem, olMarkToday, dtRemind
     Next
End Sub
' 翌日にアラーム (金曜日なら月曜日に設定)
Public Sub FollowSelectedByTomorrow()
     On Error Resume Next
     Dim objItem 'As MailItem
     Dim dtRemind As Date
     If Weekday(Now) = 6 Then
         dtRemind = DateAdd("d", 3, Now)
     Else
         dtRemind = DateAdd("d", 1, Now)
     End If
     dtRemind = FormatDateTime(dtRemind, vbShortDate) & START_TIME
     For Each objItem In ActiveExplorer.Selection
         MarkAsTaskCore objItem, olMarkTomorrow, dtRemind
     Next
End Sub
' 今週中にアラーム
Public Sub FollowSelectedByEndOfWeek()
     On Error Resume Next
     Dim objItem 'As MailItem
     Dim dtRemind As Date
     If Weekday(Now) <= 6 Then
         dtRemind = DateAdd("d", 6 - Weekday(Now), Now)
     Else
         dtRemind = DateAdd("d", 12 - Weekday(Now), Now)
     End If
     dtRemind = FormatDateTime(dtRemind, vbShortDate) & START_TIME
     For Each objItem In ActiveExplorer.Selection
         MarkAsTaskCore objItem, olMarkTomorrow, dtRemind
     Next
End Sub
' 一週間後にアラーム
Public Sub FollowSelectedByNextWeek()
     On Error Resume Next
     Dim objItem 'As MailItem
     Dim dtRemind As Date
     dtRemind = FormatDateTime(DateAdd("d", 7, Now), vbShortDate) & START_TIME
     For Each objItem In ActiveExplorer.Selection
         MarkAsTaskCore objItem, olMarkNextWeek, dtRemind
     Next
End Sub
' 任意の日時にアラーム
Public Sub FollowSelectedSpecified()
     On Error Resume Next
     Dim objItem 'As MailItem
     Dim dtRemind As Date
     dtRemind = InputBox("アラーム日時:")
     If InStr(dtRemind, ":") = 0 Then
         dtRemind = dtRemind & START_TIME
     End If
     For Each objItem In ActiveExplorer.Selection
         MarkAsTaskCore objItem, olMarkToday, dtRemind
     Next
End Sub
' フラグ設定の共通処理
Private Sub MarkAsTaskCore(ByVal objItem As Object, mkInt As OlMarkInterval, ByVal dtRemind As Date)
     Dim dtDue As Date
     dtDue = FormatDateTime(dtRemind, vbShortDate)
     With objItem
         .MarkAsTask mkInt
         .FlagStatus = olFlagMarked
         .FlagRequest = "ご確認ください"
         .TaskStartDate = Now
         .TaskDueDate = dtDue
         .ReminderTime = dtRemind
         .ReminderSet = True
         .Close olSave
     End With
End Sub


マクロの登録方法やメニューへの追加について