Spring Security OAuth2でリクエストログを出力する

Spring Security OAuth2でアクセストークンのリクエストとレスポンスのログを出力するには、Apache HttpClientを使うと簡単です。

概要

Spring Security OAuth2のアクセストークン取得はRestTemplateを利用しています。
RestTemplateはデフォルトではHttpURLConnectionを利用しますが、HttpClientを利用することもできます。
HttpClientはログレベルを設定するだけでヘッダやボディのログを出力してくれます。

OAuth2RestTemplateの場合

OAuth2RestTemplateを生成する際に以下を行うことで、アクセストークンのリクエストやレスポンスのログ出力が有効になります。アクセストークン取得後のリクエストやレスポンスは別物なので注意してください。

@Configuration
class AppConfiguration {
    @Bean
    OAuth2RestTemplate oAuth2RestTemplate(OAuth2ClientContext oAuth2ClientContext) {
        def restTemplate = new OAuth2RestTemplate(resource(), oAuth2ClientContext)

        // HttpClientを利用するように設定する
        def requestFactory = new HttpComponentsClientHttpRequestFactory()
        def accessTokenProviders = Arrays.asList(
            new AuthorizationCodeAccessTokenProvider(),
            new ImplicitAccessTokenProvider(),
            new ResourceOwnerPasswordAccessTokenProvider(),
            new ClientCredentialsAccessTokenProvider()
        )
        accessTokenProviders*.requestFactory = requestFactory
        restTemplate.accessTokenProvider = new AccessTokenProviderChain(accessTokenProviders)

        restTemplate
    }

    private resource() {
        def details = new ClientCredentialsResourceDetails()
        // TODO: client_id, client_secretなどを設定する
        details
    }
}

@RestController
class HelloController {
    @Inject
    OAuth2RestTemplate restTemplate

    @GetMapping('/hello')
    Hello helloWorld() {
        // OAuth2RestTemplateを利用してAPIを実行する
        def response = restTemplate.getForEntity("https://.../hello", Hello)
    }
}

OAuth2FeignRequestInterceptorの場合

OAuth2FeignRequestInterceptorはAccessTokenProviderを設定するメソッドを提供していないため、クラスを継承して拡張する必要があります。

class HelloOAuth2FeignRequestInterceptor extends OAuth2FeignRequestInterceptor {
    private final OAuth2ClientContext oAuth2ClientContext

    private final AccessTokenProvider accessTokenProvider = {
        // HttpClientを利用するように設定する
        def requestFactory = new HttpComponentsClientHttpRequestFactory()
        def accessTokenProviders = Arrays.asList(
            new AuthorizationCodeAccessTokenProvider(),
            new ImplicitAccessTokenProvider(),
            new ResourceOwnerPasswordAccessTokenProvider(),
            new ClientCredentialsAccessTokenProvider()
        )
        accessTokenProviders*.requestFactory = requestFactory
        new AccessTokenProviderChain(accessTokenProviders)
    }()

    private final OAuth2ProtectedResourceDetails resource = {
        def details = new ClientCredentialsResourceDetails()
        // TODO: client_id, client_secretなどを設定する
        details
    }()

    def HelloOAuth2FeignRequestInterceptor(OAuth2ClientContext oAuth2ClientContext) {
        super(oAuth2ClientContext, null)
        this.oAuth2ClientContext = oAuth2ClientContext
    }

    /**
     * @see OAuth2FeignRequestInterceptor#acquireAccessToken()
     */
    @Override
    protected OAuth2AccessToken acquireAccessToken() {
        // (中略) OAuth2FeignRequestInterceptor#acquireAccessToken() の実装をコピー
    }
}

OAuth2FeignRequestInterceptorに setAccessTokenProvider() メソッドを追加するPull Requestがあるので、将来のバージョンでは改善されるかもしれません。

github.com

ログレベルの設定

HttpClientがログを出力するようにapplication.ymlを設定します。

logging.level:
  # ヘッダのみ出力する場合
  org.apache.http.headers: DEBUG
  # ヘッダとボディを出力する場合
  org.apache.http.wire: DEBUG

アクセストークンリクエストのカスタマイズ（おまけ）

上記と同様に setTokenRequestEnhancer() を利用することで、アクセストークンのリクエストをカスタマイズできます。例えば、client_id や client_secret をボディに入れるといった独自仕様に対応できます。

    @Bean
    OAuth2RestTemplate oAuth2RestTemplate(OAuth2ClientContext oAuth2ClientContext) {
        def restTemplate = new OAuth2RestTemplate(resource(), oAuth2ClientContext)
        def accessTokenProvider = new ClientCredentialsAccessTokenProvider()
        // HttpClientを利用するように設定する
        accessTokenProvider.requestFactory = new HttpComponentsClientHttpRequestFactory()
        // アクセストークンリクエストをカスタマイズする
        accessTokenProviders*.tokenRequestEnhancer = new RequestEnhancer() {
            @Override
            void enhance(AccessTokenRequest request, OAuth2ProtectedResourceDetails resource, MultiValueMap<String, String> form, HttpHeaders headers) {
            }
        }
        restTemplate.accessTokenProvider = accessTokenProvider
        restTemplate
    }