// Trace la fonction de densité de la moyenne de n tirages à pile ou face

// initialisation

clear;
clf;

nbmax = 12; // nombre max de tirages

cmap = coolcolormap(nbmax);
xset("colormap", cmap);

// Fonctions

function [frequences]=tirages(n)
    // calcule les fréquences de n tirage à pile ou face par dénombrement
    // entrées : n : nombre de tirages (entier)
    // sorties : frequences : matrice de fréquences (réels)
    
    N = 2^n; // nombre de valeurs possibles
    resultats = zeros(N, n); // initialisation : résultats des tirages
    for i = 1:n // n° de colonne
        k = 2^(n - i); //à la colonne i, on alterne k valeurs 0 et k valeurs 1
        for j=0:2^(i - 1) - 1
            resultats(2*j*k + 1:(2*j + 1)*k, i) = 0;
            resultats((2*j + 1)*k + 1:(2*j + 2)*k, i) = 1;
        end
    end
    //disp(resultats);
    somme = sum(resultats, "c");
    frequences_non_triees = tabul(somme);
    frequences = gsort(frequences_non_triees, "lr", "i");
    frequences(:,2) = frequences(:,2)/N; // normalisation des fréquences
endfunction

// Programme principal

for i=1:nbmax
    XY = tirages(i);
    plot2d(XY(:,1), XY(:,2), style = i)
end
axe = gca();

xtitle("Tirages à pile ou face", "Valeurs de la somme", "Fréquence")
legend("n = 1", "n = 2", "n = 3", "n = 4", "n = 5", "n = 6", "n = 7",...
 "n = 8", "n = 9", "n = 10", "n = 11", "n = 12")