resource "aws_lambda_function" "athena_postgres" {
  function_name    = "my_postgres_fdw"
  handler          = "com.amazonaws.athena.connectors.postgresql.PostGreSqlMuxCompositeHandler"
  runtime          = "java11"
  timeout          = 900
  memory_size      = 10240
  role             = var.iam_role_arn

  // https://github.com/awslabs/aws-athena-query-federation/releases
  filename = "${path.module}/../terraform/athena-postgresql-2024.15.2.jar" 

  reserved_concurrent_executions = 10 // don't blow up your account limit!

  vpc_config {
    subnet_ids         = var.subnet_ids
    security_group_ids = var.security_group_ids
  }

  environment {
    variables = merge({
      disable_spill_encryption = "false"
      spill_bucket             = var.spill_bucket_name
      spill_prefix             = "fdw-spill/postgres"
      default                  = "postgres://jdbc:postgresql://${var.db_host}:${var.db_port}/?$${${var.db_credentials_secret_name}}"
      default_scale            = 0
    })
  }
}

resource "aws_athena_data_catalog" "postgres" {
  name        = "postgres"
  type        = "LAMBDA"

  parameters = {
    "function" = aws_lambda_function.athena_postgres.arn
  }
}