// Wave Shield パーカッション
// http://www.ladyada.net/make/waveshield/examples.html
// ladyada.netのサンプルをベースに武蔵野電波が改変

#include <avr/pgmspace.h>
#include "AF_Wave.h"    // Wave Shield用ライブラリ
#include "util.h"
#include "wave.h"

#define SW 6            // 接続するスイッチの数
#define SWPIN 14        // どのピンから接続するか

AF_Wave card;
Wavefile wave;
File f;

void setup() {
  Serial.begin(19200);  // エラーメッセージの出力用

  pinMode(2, OUTPUT);   // Shieldが使う4本のピン
  pinMode(3, OUTPUT);
  pinMode(4, OUTPUT);
  pinMode(5, OUTPUT);

  // スイッチを接続するピンの内部プルアップを有効に
  for(char i = SWPIN; i < SWPIN+SW; i++) {
    digitalWrite(i, HIGH);
  }

  // メモリカードにアクセスする準備
  if (!card.init_card()) {
    putstring_nl("Card init failed!");
    return;
  }
  if (!card.open_partition()) {
    putstring_nl("No partition!");
    return;
  }
  if (!card.open_filesys()) {
    putstring_nl("Couldn't open filesys");
    return;
  }
  if (!card.open_rootdir()) {
    putstring_nl("Couldn't open dir");
    return;
  }
}

void loop() {
  // スイッチを調べて、対応するwavファイルを再生
  switch (checkswitches()) {
  case 1:
    playfile("1.WAV");  // ファイル名には拡張子をつける
    break;
  case 2:
    playfile("2.WAV");
    break;
  case 3:
    playfile("3.WAV");
    break;
  case 4:
    playfile("4.WAV");
    break;
  case 5:
    playfile("5.WAV");
    break;
  case 6:
    playfile("6.WAV");
    break;
  default:              // 押されていないとき
    break;
  }

  // 再生していないのにファイルが開いていたら閉じる
  if (f && !wave.isplaying) {
    card.close_file(f);
  }
}

byte checkswitches() {
  byte pressed = 0;

  for (char k = 0; k < SW; k++) {
    char reading = digitalRead(SWPIN + k);
    if (reading == LOW) {    // キーが押されている
      delay(10);
      reading = digitalRead(SWPIN + k);
      if (reading == LOW) {  // 10ミリ秒後も押されてる
        pressed = k + 1;     // 押されているキーの番号を返す
      }
    }
  }
  return (pressed);
}

void playfile(char *name) {
  // ファイルが開いていたり再生中だったら停止処理
  if (f || wave.isplaying) {
    wave.stop();
    card.close_file(f);
  }

  f = card.open_file(name);  // wavファイルを開く
  if (f && wave.create(f)) { // ファイルから音データを得る
    wave.play();             // 再生!
  }

  delay(50);  // このディレイの大きさでスクラッチ感が変化
}