// Trace la fonction de densité de la moyenne de n tirages de dés à 6 faces

// initialisation

clear;
clf;

nbmax = 5; // nombre max de tirages

cmap = coolcolormap(nbmax);
xset("colormap", cmap);

// Fonctions

function [frequences]=tirages(n)
    // calcule les fréquences de n tirage de dés par dénombrement
    // entrées : n : nombre de tirages (entier)
    // sorties : frequences : matrice de fréquences (réels)
    
    N = 6^n; // nombre de valeurs possibles
    resultats = zeros(N, n); // initialisation : résultats des tirages
    for i = 1:n // n° de colonne
        k = 6^(n - i); //à la colonne i, on alterne k valeurs 0 et k valeurs 1
        for j=0:6^(i - 1) - 1
            for jj = 1:6
                resultats((6*j + jj - 1)*k + 1:(6*j + jj)*k, i) = jj;
            end
        end
    end
    //disp(resultats);
    somme = sum(resultats, "c");
    frequences_non_triees = tabul(somme);
    frequences = gsort(frequences_non_triees, "lr", "i");
    frequences(:,2) = frequences(:,2)/N; // normalisation des fréquences
endfunction

// Programme principal

for i=1:nbmax
    XY = tirages(i);
    plot2d(XY(:,1), XY(:,2), style = i)
end
axe = gca();

xtitle("Tirages de dés à 6 faces", "Valeurs de la somme", "Fréquence")
legend("n = 1", "n = 2", "n = 3", "n = 4", "n = 5", "n = 6", "n = 7",...
 "n = 8", "n = 9", "n = 10", "n = 11", "n = 12")